Prev: ODBC Error
Next: how do i change pixels of my photos?
From: KenSheridan via AccessMonster.com on 7 Oct 2009 18:42
Mike:

Using your existing report, list box and button, you can also do it with code
like this in the button's Click event procedure:

Dim varItem As Variant
Dim strCategoryList As String
Dim strCriteria As String
Dim ctrl As Control

Set ctrl = Me.listCategory

If ctrl.ItemsSelected.Count > 0 Then
For Each varItem In ctrl.ItemsSelected
strCategoryList = strCategoryList & ",""" & _
ctrl.ItemData(varItem) & """"
Next varItem

' remove leading comma
strCategoryList = Mid(strCategoryList, 2)

strCriteria = "Category In(" & strCategoryList & ")"

DoCmd.OpenReport "rptPartsByCategory", _
View:=acViewPreview, _
WhereCondition:=strCriteria
Else
MsgBox "No categories selected", vbInformation, "Warning"
End If

Ken Sheridan
Stafford, England

Mike Revis wrote:
>Hi Group,
>Access 2007. WinXPpro.
>
>My app has a report that lists parts by category.
>
>I found some earlier discussion in the group about filtering a report based
>on a combo box selection.
>
>I was able to do that and have the report show only one category.
>
>I would like to be able to filter the report based on a multiselect listbox.
>
>I adapted the combo box action to a list box and it works as long as I have
>multiselect = None.
>
>When I change the listbox to multiselect simple or extended the report opens
>with no data.
>
>My command button code as follows.
>
>DoCmd.OpenReport "rptPartsByCategory", acPreview, , " [Category]=' " &
>Me.listCategory & " ' "
>
>As always any thoughts, comments or suggestions are welcome.
>
>Best regards,
>Mike

--
Message posted via http://www.accessmonster.com

First  |  Prev  | 
Pages: 1 2
Prev: ODBC Error
Next: how do i change pixels of my photos?