Prev: Avery 5845
Next: Large amount of space shows on page 3 of document in Word 2007
From: Jay Freedman on 2 Jun 2010 16:33
There is no built-in provision in Word to print those lines. You could use a
macro to format the spelling and grammar errors with real wavy underlines
(best to do this to a copy of the document, not the original).

--
Regards,
Jay Freedman
Microsoft Word MVP FAQ: http://word.mvps.org
Email cannot be acknowledged; please post all follow-ups to the newsgroup so
all may benefit.

Sean wrote:
> Hello again,
>
> I didn't mean the user submitted commentaries, like editor marks. I
> meant the ones that Microsoft Word automatically makes when a word is
> spelled wrong or there is a sentence fragment. I want to preserve
> the red and green squiggly lines you get when Word detects something
> is wrong when printing.


From: Jay Freedman on 2 Jun 2010 21:00
Here's a macro to do the job. See
http://www.gmayor.com/installing_macro.htm if needed.

Sub PrintableErrors()
Dim srcDoc As Document
Dim spErr As Range
Dim grErr As Range

If Len(ActiveDocument.Path) = 0 Then
MsgBox "Save the document first!"
Exit Sub
End If

' make a copy of active document
Set srcDoc = Documents.Add( _
Template:=ActiveDocument.FullName, _
NewTemplate:=False, _
DocumentType:=wdNewBlankDocument)

' format the grammar errors
' with green wavy underlines
For Each grErr In srcDoc.GrammaticalErrors
With grErr.Font
.Underline = wdUnderlineWavy
.UnderlineColor = wdColorGreen
End With
Next

' format the spelling errors
' with red wavy underlines
For Each spErr In srcDoc.SpellingErrors
With spErr.Font
.Underline = wdUnderlineWavy
.UnderlineColor = wdColorRed
End With
Next

' turn off the nonprinting underlines
srcDoc.ShowSpellingErrors = False
srcDoc.ShowGrammaticalErrors = False
End Sub


On Wed, 2 Jun 2010 16:33:35 -0400, "Jay Freedman"
<jay.freedman(a)verizon.net> wrote:

>There is no built-in provision in Word to print those lines. You could use a
>macro to format the spelling and grammar errors with real wavy underlines
>(best to do this to a copy of the document, not the original).
>
>--
>Regards,
>Jay Freedman
>Microsoft Word MVP FAQ: http://word.mvps.org
>Email cannot be acknowledged; please post all follow-ups to the newsgroup so
>all may benefit.
>
>Sean wrote:
>> Hello again,
>>
>> I didn't mean the user submitted commentaries, like editor marks. I
>> meant the ones that Microsoft Word automatically makes when a word is
>> spelled wrong or there is a sentence fragment. I want to preserve
>> the red and green squiggly lines you get when Word detects something
>> is wrong when printing.
>
First  |  Prev  | 
Pages: 1 2
Prev: Avery 5845
Next: Large amount of space shows on page 3 of document in Word 2007