Prev: A Data manipulation question - SORRY STAT personal has changed
Next: check for variable existence, if not there put variable in.
From: "Hixon, John" on 3 Mar 2010 16:25
/*

>Subject: Re: Suppress Borders in ODS Tagsets ExceXP?

>>You can try style=minimal, though from what i've seen that can cause
>>some interesting bugs in the output.<<

>Thanks. That's an improvement, although one thing it still leave in are the borders!

>--Dav
>david.a.vandenbroucke(a)hud.gov

*/


* Use proc template to see the defn of the Minimal style (it is in the log);
proc template;
list styles;
source styles.minimal;
run; quit;

* Define a new style and change the borderspacing and
borderwidth to 0;
proc template;
define style Styles.DavidV;
parent = styles.minimal;
style Output /
bordercollapse = separate
rules = all
frame = Box
padding = 7
borderspacing = 0
borderwidth = 0;
end; quit;

* make some dummy data;
data junk;
array x{5};
do rep=1 to 10;
do i=1 to 5;
x(i)=i+3*ranuni(-1);
output;
end;
end;
run;
*Show two different styles. You need to define the odsout file ref to
be correct for your machine. First test just HTML destinations;
filename odsout "C:\temp";
ods html file="Minimal.html" path=odsout style=minimal;
proc print data=junk;
run;
ods html close;
ods html file="DavidV.html" path=odsout style=DavidV ;
proc print data=junk;
run;
ods html close;


* Now try the ExcelXP tagset. I use the XML extension, you might want to use xls extension?;
ods tagsets.ExcelXP path=odsout file="Minimal.xml" style=minimal;
proc print data=junk;
run;
ods tagsets.ExcelXP close;
ods tagsets.ExcelXP path=odsout file="DavidV_XP.xml" style=DavidV;
proc print data=junk;
run;
ods tagsets.ExcelXP close;


/*

HTH?

Cheers,

John Hixon
jhixon(a)amgen.com

*/
 | 
Pages: 1
Prev: A Data manipulation question - SORRY STAT personal has changed
Next: check for variable existence, if not there put variable in.