Prev: Macro Help
Next: Is there an Excel formula to round a date to the end of the month
From: scottay on 20 May 2010 17:33
Hi,
Can you please help? Trying to look for words in a cell if it contains
"FHA" then give me FHA. If it contains "VA" then give me VA. If it contains
"Streamline" then give me Streamiline. Anything else give me Conv. I am
trying this: =IF(ISNUMBER(SEARCH("FHA",E6)),"FHA") but I can't seem to string
the next If statements together properly.
Thanks,
Scot
From: Lars-�ke Aspelin on 20 May 2010 17:56
On Thu, 20 May 2010 14:33:01 -0700, scottay
<scottay(a)discussions.microsoft.com> wrote:

>Hi,
> Can you please help? Trying to look for words in a cell if it contains
>"FHA" then give me FHA. If it contains "VA" then give me VA. If it contains
>"Streamline" then give me Streamiline. Anything else give me Conv. I am
>trying this: =IF(ISNUMBER(SEARCH("FHA",E6)),"FHA") but I can't seem to string
>the next If statements together properly.
>Thanks,
>Scot


Try this formula:

=INDEX({"FHA","VA","Streamiline","Conv"},MATCH(TRUE,ISNUMBER(SEARCH({"FHA","VA","Streamline",""},E6)),0))

Hope this helps / Lars-�ke
From: Gary''s Student on 20 May 2010 17:58
How about:

=IF(ISNUMBER(SEARCH("FHA",E6)),"FHA",IF(ISNUMBER(SEARCH("VA",E6)),"VA",IF(ISNUMBER(SEARCH("streamline",E6)),"streamline","conv")))

--
Gary''s Student - gsnu201003
From: scottay on 20 May 2010 19:18
Perfect! Much appreciated.

"Gary''s Student" wrote:

> How about:
>
> =IF(ISNUMBER(SEARCH("FHA",E6)),"FHA",IF(ISNUMBER(SEARCH("VA",E6)),"VA",IF(ISNUMBER(SEARCH("streamline",E6)),"streamline","conv")))
>
> --
> Gary''s Student - gsnu201003
From: scottay on 20 May 2010 19:19
Works great.
Thanks!

"Lars-Åke Aspelin" wrote:

> On Thu, 20 May 2010 14:33:01 -0700, scottay
> <scottay(a)discussions.microsoft.com> wrote:
>
> >Hi,
> > Can you please help? Trying to look for words in a cell if it contains
> >"FHA" then give me FHA. If it contains "VA" then give me VA. If it contains
> >"Streamline" then give me Streamiline. Anything else give me Conv. I am
> >trying this: =IF(ISNUMBER(SEARCH("FHA",E6)),"FHA") but I can't seem to string
> >the next If statements together properly.
> >Thanks,
> >Scot
>
>
> Try this formula:
>
> =INDEX({"FHA","VA","Streamiline","Conv"},MATCH(TRUE,ISNUMBER(SEARCH({"FHA","VA","Streamline",""},E6)),0))
>
> Hope this helps / Lars-Åke
> .
>
 | 
Pages: 1
Prev: Macro Help
Next: Is there an Excel formula to round a date to the end of the month