Prev: Distributing "Large" Expressions to Remote Nodes
Next: Background color or alike for Panel && Manipulate
From: Helen Read on 4 Mar 2010 05:31
On 3/3/2010 5:50 AM, David Park wrote:
> I like that, and learning from Helen I tried again with Presentations and
> came up with the following. We don't have to use thick lines if we turn off
> the BoundaryStyle to prevent double drawing. We don't need a RegionFunction
> if we work directly, and to me a little more intuitively, with the radius
> and reverse the iterators. And we need only one ParametricDraw if we Map it
> onto the angle iterators.
>
> Needs["Presentations`Master`"]
>
> r[t_] := Sqrt[3];
> s[t_] := Sqrt[6 Cos[2 t]];
> Draw2D[
> {PolarDraw[{r[t], s[t]}, {t, 0, 2 Pi}],
> ParametricDraw[radius {Cos[t], Sin[t]}, #, {radius, r[t], s[t]},
> Mesh -> None,
> BoundaryStyle -> None]& /@ {{t, -Pi/6, Pi/6}, {t, 5 Pi/6,
> 7 Pi/6}}
> },
> ImageSize -> 400]
>

Oh, very nice. And without your package, and without the mapping, I
think my Calculus II students could handle it. They don't mind a little
copy/paste/edit if they have to do more than one ParametricPlot.

And actually, my students are familiar with, and rather like using,
PlotStyle->Thick, and are more likely to think of it than to set a
BoundaryStyle. So something like this:

r[t_] := Sqrt[3]
s[t_] := Sqrt[6 Cos[2 t]]

plot1 = PolarPlot[{r[t], s[t]}, {t, 0, 2 Pi}, PlotStyle -> Thick];
plot2 = ParametricPlot[{radius Cos[t], radius Sin[t]},
{t, -Pi/6, Pi/6}, {radius, r[t], s[t]}, Mesh -> None];
plot3 = ParametricPlot[{radius Cos[t], radius Sin[t]},
{t, 5 Pi/6, 7 Pi/6}, {radius, r[t], s[t]}, Mesh -> None];

Show[{plot1, plot2, plot3}]

I'll try this out when we get to area inside/between polar curves later
this semester. Occasionally students have asked how to shade the region;
they use Filling all the time for illustrating regions bounded by
Cartesian curves, and then wonder how to do it for polars. It was just a
little too complicated to show them how to do it with a RegionFunction,
but this should work for them.


--
Helen Read
University of Vermont

First  |  Prev  | 
Pages: 1 2
Prev: Distributing "Large" Expressions to Remote Nodes
Next: Background color or alike for Panel && Manipulate